從 xp 中的批處理腳本中刪除臨時文件

我正在尋找一個好的批處理腳本，它可以快速從 Windows（盡可能多的變體）機器（例如 Windows 臨時文件夾、所有使用者 IE 臨時文件夾等）中找到並清理所有已知的安全臨時文件夾/文件。我喜歡 CCleaner（通過 Cleanmgr.exe）之類的 UI 工具，但是當我試圖快速清理多台電腦和/或以最少的參與度清理時，最好有一個腳本。

加上一個腳本，我可以將幾個腳本連結在一起。然後可能會啟動各種防病毒和/或惡意軟體檢測器。

任何人都有一個好的或可以指向一個好的資源？

這是我寫的一個小腳本，我保存在我的 USB 實用程序驅動器上……非常適合 citrix 伺服器 :)

@echo off
Echo Started %time%
Echo Started %time% >> temps.txt
Echo Running for XP... >> temps.txt
Echo Running for XP...
FOR /F "tokens=*" %%G IN ('DIR /B /AD') DO IF EXIST "%%G\Local Settings\Temp\" (
   RMDIR /S /Q "%%G\Local Settings\Temp"
   MKDIR "%%G\Local Settings\Temp"
   Echo Cleared %%G\Local Settings\Temp
   Echo Cleared %%G\Local Settings\Temp >> temps.txt
)
FOR /F "tokens=*" %%G IN ('DIR /B /AD') DO IF EXIST "%%G\Local Settings\Temporary Internet Files\" (
   RMDIR /S /Q "%%G\Local Settings\Temporary Internet Files\"
   MKDIR "%%G\Local Settings\Temporary Internet Files\"
   Echo Cleared %%G\Local Settings\Temporary Internet Files\
   Echo Cleared %%G\Local Settings\Temporary Internet Files\ >> temps.txt
)
Echo Done.
Echo Running for Vista >> temps.txt
Echo Running for Vista...
FOR /F "tokens=*" %%G IN ('DIR /B /AD') DO IF EXIST "%%G\AppData\Local\Temp\" (
   RMDIR /S /Q "%%G\AppData\Local\Temp\"
   MKDIR "%%G\AppData\Local\Temp\"
   Echo Cleared %%G\AppData\Local\Temp\
   Echo Cleared %%G\AppData\Local\Temp\ >> temps.txt
)
FOR /F "tokens=*" %%G IN ('DIR /B /AD') DO IF EXIST "%%G\AppData\Local\Microsoft\Windows\Temporary Internet Files\" (
   RMDIR /S /Q "%%G\AppData\Local\Microsoft\Windows\Temporary Internet Files\"
   MKDIR "%%G\AppData\Local\Microsoft\Windows\Temporary Internet Files\"
   Echo Cleared %%G\Local Settings\Temporary Internet Files\
   Echo Cleared %%G\Local Settings\Temporary Internet Files\ >> temps.txt
)
Echo Done.
Echo Ended %time%
Echo Ended %time% >> temps.txt

使用風險自負，等等……這會刪除東西。

我從文件和設置文件夾或 Vista 上的使用者執行它。您可以輕鬆地將 CD 命令放在頂部以從任何您想要的地方執行它。

cd %userprofile%
cd ..

此外，根據我的經驗，在任何時候清除臨時文件夾通常都是安全的。使用臨時文件的程序將鎖定它們，並且此腳本將在該文件上出錯並繼續執行。

IF EXIST 行在這里特別好，它可以防止腳本在 NetworkService 和類似文件夾中創建文件夾，如果您沒有在 Vista 或 XP 上執行它，該部分的執行速度非常快。

在您執行腳本的地方創建 temps.txt 日誌文件

編輯：來自 Freenode 上##windows-server 的建議： 問：為什麼不檢測它在開始時執行的作業系統並執行相應的部分？答：我經常在離線媒體上使用該腳本，例如已提取的硬碟驅動器。

引用自：https://serverfault.com/questions/19380